ASP 페이징 객체지향 흉내내서 구현하기

페이징 처리는 구현할 때 마다 헷갈려서 짜증나.

오늘도 어찌 어찌해서 구현은 했다만... 영 맘에 안든다.

아래 내용은 단순 참고용이니까 시간내서 읽어보려고 포스팅 한다.

삭제 방지 위해서 붙여 넣기 신공~

출처 : http://expert0226.tistory.com/61

ASP 페이징 소스

페이징이 필요한 부분에 Sever.Execute 또는 include 로 구겨(?) 넣으면 OKay.

이 페이징을 삽이하는 페이지에 추가해야 할 자바스크립트:

이 페이지를 삽입하는 페이지는 자바스크립트로 fnList 를 구현해야 하고 

당연히 fnList 에서는 window.location.href 를 사용해서 인자 값을 

GET 방식으로 넘겨주는 부분이 필요하겠지

  function fnList(page)
  {
    window.location.href = "?page=" + page; // 기타 인자값 "&idxCategory=<%= idxCategory %>";
  }

이 페이징을 삽입하는 페이지에 추가해야 할 ASP 코드:

Dim Page       // 현재 페이지 번호
Dim PageRange  // 페이징에서 보여질 갯수 ex)  << < 11 12 13 14 15 > >> 의 경우 5 가 됨
Dim PageCount  // 총 페이징 수(마지막 페이지 수)

소스: (아래 부분을 클릭하고 Ctrl + A 를 누르면 깔끔하게 선택 완료)

Server.Excuete 를 쓴 소스: (아래 부분을 클릭하고 Ctrl + A 를 누르면 깔끔하게 선택 완료)

<%
  Option Explicit

'Server.Execute "/Execute/ChkRequest.asp"

Response.CacheControl = "no-cache"
  Response.AddHeader "Pragma", "no-cache"
  Response.Expires = -1

Dim cBoardMgr
  Dim cBoard
  Dim arrBoard
  Dim BoardName
  Dim SearchField
  Dim SearchText
  Dim page
  Dim pageSize
  Dim pageRange
  Dim rowCount
  Dim pageCount
  Dim cntGet
  Dim i
  Dim max

BoardName = Request("BoardName")

If BoardName = "" Then
    BoardName = "tbBoardNotice"
  End If
  
  SearchField = Trim(Request("SearchField"))
  SearchText = Trim(Request("SearchText"))
  page = Request("page")

pageSize = 10
  pageRange = 10

If Len(page) = 0 Then
    page = 1
  End if

SearchField = Replace(SearchField, "'", "&apos;")
  SearchText = Replace(SearchText, "'", "&apos;")

Set cBoardMgr = new clsBoardMgr
  Set cBoard = new clsBoard

cBoardMgr.BoardName = BoardName
  cBoardMgr.SearchField = SearchField
  cBoardMgr.SearchText = SearchText
  
  rowCount = cBoardMgr.SelectRecordCount()

pageCount = Int((rowCount - 1) / pageSize) + 1

If page * pageSize > rowCount Then
    cntGet = rowCount - ((pageCount - 1) * pageSize)
  Else
    cntGet = pageSize
  End If
  
  arrBoard = cBoardMgr.SelectByPage(page, pageSize, cntGet)
%>


<html>
<head>
<title>테스트용 소스</title>
<meta http-equiv="Content-Type" content="text/html; charset=euc-kr">
<link href="boardstyle.css" rel="stylesheet" type="text/css">
<script src="/javascript/default.js" type="text/javascript"></script>
<script type="text/javascript">
<!--
  var Search;

Search = "&SearchField=<%= SearchField %>&SearchText=<%= SearchText %>";

function fnSearch()
  {
    frmMine.SearchText.value = frmMine.SearchText.value.trim();

frmMine.submit();
  }

function fnList(page)
  {
    window.location.href = "?BoardName=<%= BoardName %>&page=" + page + Search;
  }

function fnWrite()
  {
    window.location.href = "bizdata_write.asp?BoardName=<%= BoardName %>";
  }

function fnView(idx) 
  {
    window.location.href = "bizdata_view.asp?BoardName=<%= BoardName %>&idx=" + idx + "&page=<%= page %>" + Search;
  }
//-->
</script>
</head>
<body>
<table width="640" border="0" cellspacing="0" cellpadding="0">
  <tr> 
    <td>
      <table width="100%" border="0" cellpadding="0" cellspacing="0">
        <tr bgcolor="#506bb0"> 
                       <td height="3" colspan="4"></td>
                      </tr>
                      <tr> 
                        <td bgcolor="#fafafa" width="40" height="30" align="center"><strong>NO</strong></td>
          <td align="center"><strong>SUBJECT</strong></td>
          <td width="80" align="center"><strong>DATE</strong></td>
          <td width="70" align="center"><strong>VIEW</strong></td>
        </tr>
        <tr> 
          <td bgcolor="#506bb0" height="1" colspan="7"></td>
        </tr>
        <tr> 
          <td bgcolor="#FFFFFF" height="5" colspan="7"></td>
        </tr>
      </table>
      <table width="100%" border="0" cellspacing="0" cellpadding="0">
        <tr> 
          <td height="1" colspan="4" bgcolor="#eeeeee"></td>
        </tr>
<%
  If IsArray(arrBoard) = True then
    max = cntGet - 1

For i = 0 To max
      cBoard.Idx = arrBoard(0, i)
      cBoard.Title = arrBoard(1, i)
      cBoard.FilePath = arrBoard(2, i)
      cBoard.ImagePath = arrBoard(3, i)
      cBoard.Context = arrBoard(4, i)
      cBoard.IsHtml = arrBoard(5, i)
      cBoard.Count = arrBoard(6, i)
      cBoard.RegDate = arrBoard(7, i)
%> 
        <tr> 
          <td width="40" align="center"><%= rowCount - ((page - 1) * pageSize) - i %></td>
          <td style="padding-left:10" style="cursor: hand;" onClick="fnView(<%= cBoard.Idx %>);"><%= cBoard.Title %></td>
          <td width="80" align="center"><%= FormatDateTime(cBoard.RegDate, vbShortDate) %></td>
          <td width="70" height="29" align="center"><%= cBoard.Count %></td>
        </tr>
        <tr> 
          <td height="1" colspan="4" bgcolor="#eeeeee"></td>
        </tr>
<%
    Next
  Else
%>
        <tr> 
          <td align="center" valign="center" colspan="4" height="289" style="font: red;"><b>등록된 게시물이 없습니다.</b></td>
        </tr>
        <tr> 
          <td height="1" colspan="4" bgcolor="#eeeeee"></td>
        </tr>
<%
  End If
%>
      </table>
      <table width="100%" border="0" cellspacing="0" cellpadding="0">
        <tr> 
          <td height="10" colspan="3"></td>
        </tr>
        <tr> 
          <td width="62" height="21"></td>
          <td align="center">
            
          </td>
          <td width="62"><img src="images/bt_write.gif" width="62" height="21" border="0" style="cursor: hand;" onClick="fnWrite();"></td>
        </tr>
        <tr> 
          <td height="10" colspan="3"></td>
        </tr>
       </table>
      <table width="100%" border="0" cellspacing="0" cellpadding="0">
        <tr> 
          <td  height="1" bgcolor="#eeeeee"></td>
        </tr>
      </table>
      <table width="100%" border="0" cellspacing="0" cellpadding="0">
        <tr> 
          <td height="15"></td>
        </tr>
        <tr> 
          <td align="center">
            <table width="240" border="0" cellspacing="0" cellpadding="0">
            <FORM NAME="frmMine" METHOD="POST" ACTION="bizdata_list.asp">
            <INPUT TYPE="hidden" NAME="BoardName" VALUE="<%= BoardName %>">
              <tr> 
                <td>
                  <select name="SearchField">
                    <option value="title" <% If SearchField = "title" Then Response.Write "selected" End If %>>제목</option>
                    <option value="context" <% If SearchField = "context" Then Response.Write "selected" End If %>>내용</option>
                  </select>
                </td>
                <td width="10"></td>
                <td width="120"><input name="SearchText" type="text" maxlength="10" style="width:120px;" value="<%= SearchText %>" onFocus="this.select();" onBlur="this.value = this.value.trim();"></td>
                <td width="11"></td>
                <td width="50"><img src="images/bt_search.gif" width="50" height="15" border="0" style="cursor: hand;" onClick="fnSearch();"></td>
              </tr>
            </FORM>
            </table>
          </td>
        </tr>
        <tr> 
          <td height="15"></td>
        </tr>
      </table>
    </td>
    </tr>
</table>
</body>
</html>
<%  
  Set cBoard = Nothing  
  Set cBoardMgr = Nothing
%>

객체지향을 흉내내기

위한 clsBoardMgr.asp 소스: (아래 부분을 클릭하고 Ctrl + A 를 누르면 깔끔하게 선택 완료)

<%
  Class clsBoardMgr
    Private mErrCnt
    Private mErrMsg
    Private mBoardName
    Private mSearchField
    Private mSearchText

Private adoCn
    Private adoRs

Private Sub Class_Initialize()
      mErrCnt = 0
      mErrMsg = ""

set adoCn = server.CreateObject("ADODB.Connection")
      adoCn.Open(Application("ConnectionString"))
      
      set adoRs = server.CreateObject("ADODB.Recordset")
      adoRs.cursortype = 1
      adoRs.cursorlocation = 3
      adoRs.locktype = 3
    End Sub

Private Sub Class_Terminate()
      If Not adoRs Is Nothing Then
        Set adoRs = Nothing
      End If
      
      If Not adoCn Is Nothing Then
        Set adoCn = Nothing
      End If
    End Sub

Public Property Get BoardName()
      BoardName = mBoardName
    End Property

Public Property Let BoardName(arg)
      mBoardName = arg
    End Property

Public Property Get SearchField()
      SearchField = mSearchField
    End Property

Public Property Let SearchField(arg)
      mSearchField = arg
    End Property

Public Property Get SearchText()
      SearchText = mSearchText
    End Property

Public Property Let SearchText(arg)
      mSearchText = arg
    End Property

Public Function SelectRecordCount()
      Dim SQL
      
      SQL = ""
      SQL = SQL & " SELECT count(*) FROM " & BoardName

If SearchText = "" Then

Else
        SQL = SQL & " WHERE " & SearchField & " LIKE '%" & SearchText & "%' "
      End If

adoRs.Open SQL, adoCn

SelectRecordCount = adoRs(0)

adoRs.close
    End Function

Public Function SelectByPage(page, pageSize, cntGet)
      Dim SQL
      
      SQL = ""
      SQL = SQL & " SELECT TOP " & cntGet & " * " 
      SQL = SQL & " FROM ( "
      SQL = SQL & "    SELECT TOP " & cntGet & " * "
      SQL = SQL & "    FROM ( "
      SQL = SQL & "      SELECT TOP " & (page * pageSize)
      SQL = SQL & "          idx, title, filePath, imagePath, context "
      SQL = SQL & "        , isHtml, count, regDate "
      SQL = SQL & "      FROM " & BoardName

If SearchText = "" Then

Else
        SQL = SQL & "    WHERE " & SearchField & " LIKE '%" & SearchText & "%' "
      End If

SQL = SQL & "      ORDER BY idx DESC "
      SQL = SQL & "    ) as tbTmp1 "
      SQL = SQL & "    ORDER BY idx ASC "
      SQL = SQL & " ) as tbTmp2 "
      SQL = SQL & " ORDER BY idx DESC "

adoRs.Open SQL, adoCn

If adoRs.EOF Then
        
      Else
        SelectByPage = adoRs.getRows()
      End If

adoRs.close
    End Function

Public Function SelectByIdx(idx)
      Dim SQL

SQL = ""
      SQL = SQL & " UPDATE " & BoardName & " SET "
      SQL = SQL & "     count = count + 1 "      
      SQL = SQL & " WHERE idx = " & idx

'Response.Write SQL
      adoCn.Execute SQL
      
      SQL = ""
      SQL = SQL & " SELECT "
      SQL = SQL & "      idx, title, filePath, imagePath, context "
      SQL = SQL & "    , isHtml, count, regDate "
      SQL = SQL & " FROM " & BoardName & " "
      SQL = SQL & " WHERE idx = " & idx

adoRs.Open SQL, adoCn

If adoRs.EOF Then
        
      Else
        SelectByIdx = adoRs.getRows()
      End If

adoRs.close
    End Function

Public Function SelectNextByIdx(idx)
      Dim SQL

SQL = ""
      SQL = SQL & " SELECT TOP 1 "
      SQL = SQL & "      idx, title, filePath, imagePath, context "
      SQL = SQL & "    , isHtml, count, regDate "
      SQL = SQL & " FROM " & BoardName & " "
      SQL = SQL & " WHERE idx > " & idx

If SearchText = "" Then

Else
        SQL = SQL & " AND " & SearchField & " LIKE '%" & SearchText & "%' "
      End If

SQL = SQL & " ORDER BY idx "

adoRs.Open SQL, adoCn

If adoRs.EOF Then
        
      Else
        SelectNextByIdx = adoRs.getRows()
      End If

adoRs.close
    End Function

Public Function SelectPrevByIdx(idx)
      Dim SQL

SQL = ""
      SQL = SQL & " SELECT TOP 1 "
      SQL = SQL & "      idx, title, filePath, imagePath, context "
      SQL = SQL & "    , isHtml, count, regDate "
      SQL = SQL & " FROM " & BoardName & " "
      SQL = SQL & " WHERE idx < " & idx

If SearchText = "" Then

Else
        SQL = SQL & " AND " & SearchField & " LIKE '%" & SearchText & "%' "
      End If

SQL = SQL & " ORDER BY idx DESC "

adoRs.Open SQL, adoCn

If adoRs.EOF Then
        
      Else
        SelectPrevByIdx = adoRs.getRows()
      End If

adoRs.close
    End Function

Public Function Insert(title, filePath, imagePath, context, isHtml)
      Dim SQL
      Dim cnt

SQL = ""
      SQL = SQL & " INSERT INTO " & BoardName & " "
      SQL = SQL & "    ( "
      SQL = SQL & "         title, filePath, imagePath, context, isHtml "
      SQL = SQL & "    ) "      
      SQL = SQL & " VALUES "
      SQL = SQL & "     (  "
      SQL = SQL & "         '" & title & "'"
      SQL = SQL & "       , '" & filePath & "'"
      SQL = SQL & "       , '" & imagePath & "'"
      SQL = SQL & "       , '" & context & "'"
      SQL = SQL & "       ,  " & isHtml
      SQL = SQL & "     )  "

adoCn.Execute SQL, cnt

Insert = cnt
    End Function

Public Function Update(idx, title, filePath, imagePath, context, isHtml)
      Dim SQL
      Dim cnt

SQL = ""
      SQL = SQL & " UPDATE " & BoardName & " SET "
      SQL = SQL & "     title = '" & title & "'"

If Trim(filePath) = "" Then
      
      Else      
        SQL = SQL & "  , filePath = '" & filePath & "'"
      End If

If Trim(imagePath) = "" Then
      
      Else      
        SQL = SQL & "  , imagePath = '" & imagePath & "'"
      End If

SQL = SQL & "  , context = '" & context & "'"
      SQL = SQL & "  , isHtml = " & isHtml
      
      SQL = SQL & " WHERE idx = " & idx

adoCn.Execute SQL, cnt

Update = cnt
    End Function

Public Function Delete(idx)
      Dim SQL
      Dim cnt

SQL = ""
      SQL = SQL & " DELETE FROM " & BoardName & " "      
      SQL = SQL & " WHERE idx = " & idx

adoCn.Execute SQL, cnt

Delete = cnt
    End Function
  End Class
%>

객체지향을 흉내내기 위한 clsBoard.asp 소스: (아래 부분을 클릭하고 Ctrl + A 를 누르면 깔끔하게 선택 완료)

<%
  Class clsBoard
    Private mErrCnt
    Private mErrMsg
    Private mIdx
    Private mTitle
    Private mFilePath
    Private mImagePath
    Private mContext
    Private mIsHtml
    Private mCount
    Private mRegDate

Private Sub Class_Initialize()
      mErrCnt = 0
      mErrMsg = ""
    End Sub

Private Sub Class_Terminate()

End Sub

Public Property Get ErrCnt()
      ErrCnt = mErrCnt
    End Property

Public Property Get ErrMsg()
      ErrMsg = mErrMsg
    End Property

Public Property Get Idx()
      Idx = mIdx
    End Property

Public Property Let Idx(arg)
      mIdx = arg
    End Property

Public Property Get Title()
      Title = mTitle
    End Property

Public Property Let Title(arg)
      mTitle = arg
    End Property

Public Property Get FilePath()
      FilePath = mFilePath
    End Property

Public Property Let FilePath(arg)
      mFilePath = arg
    End Property

Public Property Get ImagePath()
      ImagePath = mImagePath
    End Property

Public Property Let ImagePath(arg)
      mImagePath = arg
    End Property

Public Property Get Context()
      Context = mContext
    End Property

Public Property Let Context(arg)
      mContext = arg
    End Property

Public Property Get IsHtml()
      IsHtml = mIsHtml
    End Property

Public Property Let IsHtml(arg)
      mIsHtml = arg
    End Property

Public Property Get Count()
      Count = mCount
    End Property

Public Property Let Count(arg)
      mCount = arg
    End Property

Public Property Get RegDate()
      RegDate = mRegDate
    End Property

Public Property Let RegDate(arg)
      mRegDate = arg
    End Property
  End Class
%>

저작자표시 비영리 변경금지

'Programming > ASP' 카테고리의 다른 글

ms-sql 엑셀 파일로 저장 (0)	2010.02.11
ASP request.ServerVariable("QUERY_STRING") (0)	2010.02.05
ASP 연산 함수 (0)	2010.02.03
CreateParameter 메서드(ADO) (0)	2010.02.02
Eclipse 에서 ASP 사용하기 (0)	2010.02.02

Dualist☆

ASP 페이징 객체지향 흉내내서 구현하기

'Programming > ASP' 카테고리의 다른 글

티스토리툴바

ASP 페이징 객체지향 흉내내서 구현하기

'Programming > ASP' 카테고리의 다른 글

'Programming/ASP' Related Articles

티스토리툴바